/[projet1]/public/atari/demos/next/charts/charts_2.int/next_045.s
Defence Force logotype

Annotation of /public/atari/demos/next/charts/charts_2.int/next_045.s

Parent Directory Parent Directory | Revision Log Revision Log


Revision 65 - (hide annotations)
Thu Apr 23 19:33:45 2009 UTC (11 years, 1 month ago) by dbug
File size: 14377 byte(s)
Added the intro of the second charts
1 dbug 65 affiche_balle macro
2     move.l offset_balle,a2
3     moveq #64,d1
4     ball_2
5     lea buf_x15_balle,a0
6     lea buf_masque,a3
7     move.l buf1,a1
8    
9     add.w (a2)+,a1
10     add.w (a2)+,a0
11     add.w (a2)+,a3
12    
13     movem.l (a3)+,d0/d2/d3/d4/d5/d6 ; 6*4=24
14     and.l d0,(a1)
15     and.l d0,4(a1)
16     and.l d2,8(a1)
17     and.l d2,12(a1)
18    
19     and.l d3,160(a1)
20     and.l d3,164(a1)
21     and.l d4,168(a1)
22     and.l d4,172(a1)
23    
24     and.l d5,320(a1)
25     and.l d5,324(a1)
26     and.l d6,328(a1)
27     and.l d6,332(a1)
28    
29     movem.l (a3)+,d0/d2/d3/d4/d5/d6 ; 6*4=24
30     and.l d0,480(a1)
31     and.l d0,484(a1)
32     and.l d2,488(a1)
33     and.l d2,492(a1)
34    
35     and.l d3,640(a1)
36     and.l d3,644(a1)
37     and.l d4,648(a1)
38     and.l d4,652(a1)
39    
40     and.l d5,800(a1)
41     and.l d5,804(a1)
42     and.l d6,808(a1)
43     and.l d6,812(a1)
44    
45     movem.l (a3)+,d0/d2/d3/d4/d5/d6 ; 6*4=24
46     and.l d0,960(a1)
47     and.l d0,964(a1)
48     and.l d2,968(a1)
49     and.l d2,972(a1)
50    
51     and.l d3,1120(a1)
52     and.l d3,1124(a1)
53     and.l d4,1128(a1)
54     and.l d4,1132(a1)
55    
56     and.l d5,1280(a1)
57     and.l d5,1284(a1)
58     and.l d6,1288(a1)
59     and.l d6,1292(a1)
60    
61     movem.l (a3)+,d0/d2/d3/d4/d5/d6 ; 6*4=24
62     and.l d0,1440(a1)
63     and.l d0,1444(a1)
64     and.l d2,1448(a1)
65     and.l d2,1452(a1)
66    
67     and.l d3,1600(a1)
68     and.l d3,1604(a1)
69     and.l d4,1608(a1)
70     and.l d4,1612(a1)
71    
72    
73    
74     movem.l (a0)+,d0/d2/d3/d4/d5/d6 ; 6*4=24
75     or.l d0,(a1)
76     or.l d2,4(a1)
77     or.l d3,8(a1)
78     or.l d4,12(a1)
79    
80     or.l d5,160(a1)
81     or.l d6,164(a1)
82     movem.l (a0)+,d0/d2/d3/d4/d5/d6 ; 6*4=24
83     or.l d0,168(a1)
84     or.l d2,172(a1)
85    
86     or.l d3,320(a1)
87     or.l d4,324(a1)
88     or.l d5,328(a1)
89     or.l d6,332(a1)
90    
91     movem.l (a0)+,d0/d2/d3/d4/d5/d6 ; 6*4=24
92     or.l d0,480(a1)
93     or.l d2,484(a1)
94     or.l d3,488(a1)
95     or.l d4,492(a1)
96    
97     or.l d5,640(a1)
98     or.l d6,644(a1)
99     movem.l (a0)+,d0/d2/d3/d4/d5/d6 ; 6*4=24
100     or.l d0,648(a1)
101     or.l d2,652(a1)
102    
103     or.l d3,800(a1)
104     or.l d4,804(a1)
105     or.l d5,808(a1)
106     or.l d6,812(a1)
107    
108     movem.l (a0)+,d0/d2/d3/d4/d5/d6 ; 6*4=24
109     or.l d0,960(a1)
110     or.l d2,964(a1)
111     or.l d3,968(a1)
112     or.l d4,972(a1)
113    
114     or.l d5,1120(a1)
115     or.l d6,1124(a1)
116     movem.l (a0)+,d0/d2/d3/d4/d5/d6 ; 6*4=24
117     or.l d0,1128(a1)
118     or.l d2,1132(a1)
119    
120     or.l d3,1280(a1)
121     or.l d4,1284(a1)
122     or.l d5,1288(a1)
123     or.l d6,1292(a1)
124    
125     movem.l (a0)+,d0/d2/d3/d4/d5/d6 ; 6*4=24
126     or.l d0,1440(a1)
127     or.l d2,1444(a1)
128     or.l d3,1448(a1)
129     or.l d4,1452(a1)
130    
131     or.l d5,1600(a1)
132     or.l d6,1604(a1)
133     movem.l (a0)+,d0/d2/d3/d4/d5/d6 ; 6*4=24
134     or.l d0,1608(a1)
135     or.l d2,1612(a1)
136    
137     dbra d1,ball_2
138     move.l a2,offset_balle
139    
140     cmp.l #fin_table_balle,offset_balle
141     bmi.s saute
142     move.l #table_balle,offset_balle
143     saute
144     endm
145    
146     trace_points macro
147     move.l #points,a2
148     moveq #50-1,d7
149     point_suivant
150     move.l buf1,a1
151     move.w 2(a2),d0
152     move.w (a2),d1
153     move.w d1,d2
154     lsr.w #4,d1
155     lsl.w #3,d1
156     add.w d1,d0
157     move.w d2,d1
158     and.b #%11110000,d2
159     sub.w d2,d1
160     moveq #15,d2
161     sub.w d1,d2
162     move.w 0(a1,d0.w),d1
163     bset.l d2,d1
164     move.w d1,0(a1,d0.w)
165    
166     move.w 4(a2),d0
167     add.w d0,(a2)
168     move.w 6(a2),d0
169     add.w d0,2(a2)
170    
171     cmp.w #320,(a2)
172     bpl.s init_0
173     cmp.w #160*199,2(a2)
174     bpl.s init_0
175     tst.w (a2)
176     bmi.s init_0
177     tst.w 2(a2)
178     bmi.s init_0
179     lea 8(a2),a2
180     dbra d7,point_suivant
181     bra fin_point
182    
183     init_0
184     move.w #160,(a2)
185     move.w #160*90,2(a2)
186     lea 8(a2),a2
187     dbra d7,point_suivant
188     fin_point
189     endm
190    
191     reflete macro
192     move.l buf1,a2
193     lea 160*150(a2),a2
194     move.l a2,a1
195     moveq #50-1,d0
196     ref
197     lea -320(a2),a2
198     move.l a2,a0
199     move.l (a0)+,(a1)+
200     move.l (a0)+,(a1)+
201     move.l (a0)+,(a1)+
202     move.l (a0)+,(a1)+
203     move.l (a0)+,(a1)+
204     move.l (a0)+,(a1)+
205     move.l (a0)+,(a1)+
206     move.l (a0)+,(a1)+
207     move.l (a0)+,(a1)+
208     move.l (a0)+,(a1)+
209     move.l (a0)+,(a1)+
210     move.l (a0)+,(a1)+
211     move.l (a0)+,(a1)+
212     move.l (a0)+,(a1)+
213     move.l (a0)+,(a1)+
214     move.l (a0)+,(a1)+
215     move.l (a0)+,(a1)+
216     move.l (a0)+,(a1)+
217     move.l (a0)+,(a1)+
218     move.l (a0)+,(a1)+
219     move.l (a0)+,(a1)+
220     move.l (a0)+,(a1)+
221     move.l (a0)+,(a1)+
222     move.l (a0)+,(a1)+
223     move.l (a0)+,(a1)+
224     move.l (a0)+,(a1)+
225     move.l (a0)+,(a1)+
226     move.l (a0)+,(a1)+
227     move.l (a0)+,(a1)+
228     move.l (a0)+,(a1)+
229     move.l (a0)+,(a1)+
230     move.l (a0)+,(a1)+
231     move.l (a0)+,(a1)+
232     move.l (a0)+,(a1)+
233     move.l (a0)+,(a1)+
234     move.l (a0)+,(a1)+
235     move.l (a0)+,(a1)+
236     move.l (a0)+,(a1)+
237     move.l (a0)+,(a1)+
238     move.l (a0)+,(a1)+
239     dbra d0,ref
240     endm
241    
242     affiche_texte macro
243     move.l offset_pos_texte,a2
244     move.l (a2)+,d0
245     move.l a2,offset_pos_texte
246     tst.l d0
247     bne.s saute_charge_texte
248     bsr charge_texte
249     lea pos_texte,a2
250     move.l (a2)+,d0
251     move.l a2,offset_pos_texte
252     saute_charge_texte
253     lea buf_fonte,a0
254     move.l buf1,a1
255     add.l d0,a1
256     moveq #7,d0
257     recop_buf
258     move.l (a0)+,(a1)+
259     move.l (a0)+,(a1)+
260     move.l (a0)+,(a1)+
261     move.l (a0)+,(a1)+
262     move.l (a0)+,(a1)+
263     move.l (a0)+,(a1)+
264     move.l (a0)+,(a1)+
265     move.l (a0)+,(a1)+
266     move.l (a0)+,(a1)+
267     move.l (a0)+,(a1)+
268     move.l (a0)+,(a1)+
269     move.l (a0)+,(a1)+
270     move.l (a0)+,(a1)+
271     move.l (a0)+,(a1)+
272     move.l (a0)+,(a1)+
273     move.l (a0)+,(a1)+
274     move.l (a0)+,(a1)+
275     move.l (a0)+,(a1)+
276     move.l (a0)+,(a1)+
277     move.l (a0)+,(a1)+
278     move.l (a0)+,(a1)+
279     move.l (a0)+,(a1)+
280     move.l (a0)+,(a1)+
281     move.l (a0)+,(a1)+
282     move.l (a0)+,(a1)+
283     move.l (a0)+,(a1)+
284     move.l (a0)+,(a1)+
285     move.l (a0)+,(a1)+
286     move.l (a0)+,(a1)+
287     move.l (a0)+,(a1)+
288     move.l (a0)+,(a1)+
289     move.l (a0)+,(a1)+
290     move.l (a0)+,(a1)+
291     move.l (a0)+,(a1)+
292     move.l (a0)+,(a1)+
293     move.l (a0)+,(a1)+
294     move.l (a0)+,(a1)+
295     move.l (a0)+,(a1)+
296     move.l (a0)+,(a1)+
297     move.l (a0)+,(a1)+
298     dbra d0,recop_buf
299     endm
300    
301     palette_1 macro
302     move.l #$00000777,$ffff8240.w
303     move.l #$00400150,$ffff8244.w
304     move.l #$02600370,$ffff8248.w
305     move.l #$04040535,$ffff824c.w
306     move.l #$06460757,$ffff8250.w
307     move.l #$05000700,$ffff8254.w
308     move.l #$07400750,$ffff8258.w
309     move.l #$07600770,$ffff825c.w
310     endm
311    
312     palette_2 macro
313     move.l #$00020557,$ffff8240.w
314     move.l #$00300040,$ffff8244.w
315     move.l #$01500260,$ffff8248.w
316     move.l #$03030424,$ffff824c.w
317     move.l #$05350646,$ffff8250.w
318     move.l #$04000600,$ffff8254.w
319     move.l #$06300640,$ffff8258.w
320     move.l #$06500660,$ffff825c.w
321     endm
322    
323     ;
324     ;
325     ; The Balls Demo Copyright 1990 Dbug II from T.T.Z.P. Inc.
326     ;
327     ;
328    
329     jmp gemdos_init
330    
331    
332     debut_programme
333     pea main
334     move.w #$26,-(sp)
335     trap #14
336     addq.l #6,sp
337     clr.w -(sp)
338     trap #1
339    
340     main
341     move.b #0,$ffff8260.w
342     jsr initialisations
343    
344     move.l #buf_ecran,d0
345     and.l #$ffffff00,d0
346     addi.l #256,d0
347     move.l d0,buf1
348     addi.l #32000,d0
349     move.l d0,buf2
350    
351     jsr cls
352     jsr affiche_presentation
353     jsr charge_graphiques
354     jsr init_buffers
355     jsr convert
356     jsr charge_texte
357     jsr vbl_on
358    
359     loop
360     lea page_de_fonds,a0
361     move.l buf1,a1
362     move #151-1,d0
363     recopie_fonds
364     rept 40
365     move.l (a0)+,(a1)+
366     endr
367     dbra d0,recopie_fonds
368    
369     affiche_texte
370     trace_points
371     affiche_balle
372     reflete
373    
374     commute_ecran
375     move.l buf1,d0 ; charge adresse dans d0
376     asr.l #8,d0 ; prend l'octet faible
377     move.b d0,$ffff8203.w ; stocke dans registre video
378     asr.l #8,d0 ; idem pour l'octet fort
379     move.b d0,$ffff8201.w
380    
381     move.w #$25,-(sp) ; vsync
382     trap #14
383     addq.l #2,sp ; retour au programme principal
384    
385     move.l buf2,d0 ; puis on swappe les adresses logique-physique
386     move.l buf1,buf2
387     move.l d0,buf1
388    
389     cmpi.b #$39,$fffffc02.w
390     bne loop
391    
392     sort_loop
393     move.w #$000,$ffff8240.w
394    
395     jsr vbl_off
396     jsr cls
397     rts
398    
399     *****************
400     *
401     * Sous Routines *
402     *
403     *****************
404    
405     charge_texte
406     move.l offset_texte,a2
407     lea buf_fonte,a5
408     move.l #gfx_fonte,a6
409    
410     move.l #19,d7
411     aff_fnt
412     moveq #0,d0
413     moveq #0,d1
414     move.b (a2)+,d0
415     move.b (a2)+,d1
416     eor.b #77,d0
417     eor.b #77,d1
418     lsl.w #5,d0
419     lsl.w #5,d1
420    
421     move.l a6,a0
422     move.l a6,a1
423     add.l d0,a0
424     add.l d1,a1
425    
426     move.b (a0)+,0(a5)
427     move.b (a1)+,1(a5)
428     move.b (a0)+,2(a5)
429     move.b (a1)+,3(a5)
430     move.b (a0)+,4(a5)
431     move.b (a1)+,5(a5)
432     move.b (a0)+,6(a5)
433     move.b (a1)+,7(a5)
434    
435     move.b (a0)+,160(a5)
436     move.b (a1)+,161(a5)
437     move.b (a0)+,162(a5)
438     move.b (a1)+,163(a5)
439     move.b (a0)+,164(a5)
440     move.b (a1)+,165(a5)
441     move.b (a0)+,166(a5)
442     move.b (a1)+,167(a5)
443    
444     move.b (a0)+,320(a5)
445     move.b (a1)+,321(a5)
446     move.b (a0)+,322(a5)
447     move.b (a1)+,323(a5)
448     move.b (a0)+,324(a5)
449     move.b (a1)+,325(a5)
450     move.b (a0)+,326(a5)
451     move.b (a1)+,327(a5)
452    
453     move.b (a0)+,480(a5)
454     move.b (a1)+,481(a5)
455     move.b (a0)+,482(a5)
456     move.b (a1)+,483(a5)
457     move.b (a0)+,484(a5)
458     move.b (a1)+,485(a5)
459     move.b (a0)+,486(a5)
460     move.b (a1)+,487(a5)
461    
462     move.b (a0)+,640(a5)
463     move.b (a1)+,641(a5)
464     move.b (a0)+,642(a5)
465     move.b (a1)+,643(a5)
466     move.b (a0)+,644(a5)
467     move.b (a1)+,645(a5)
468     move.b (a0)+,646(a5)
469     move.b (a1)+,647(a5)
470    
471     move.b (a0)+,800(a5)
472     move.b (a1)+,801(a5)
473     move.b (a0)+,802(a5)
474     move.b (a1)+,803(a5)
475     move.b (a0)+,804(a5)
476     move.b (a1)+,805(a5)
477     move.b (a0)+,806(a5)
478     move.b (a1)+,807(a5)
479    
480     move.b (a0)+,960(a5)
481     move.b (a1)+,961(a5)
482     move.b (a0)+,962(a5)
483     move.b (a1)+,963(a5)
484     move.b (a0)+,964(a5)
485     move.b (a1)+,965(a5)
486     move.b (a0)+,966(a5)
487     move.b (a1)+,967(a5)
488    
489     move.b (a0)+,1120(a5)
490     move.b (a1)+,1121(a5)
491     move.b (a0)+,1122(a5)
492     move.b (a1)+,1123(a5)
493     move.b (a0)+,1124(a5)
494     move.b (a1)+,1125(a5)
495     move.b (a0)+,1126(a5)
496     move.b (a1)+,1127(a5)
497    
498     add.l #8,a5
499     dbra d7,aff_fnt
500    
501     move.l a2,offset_texte
502     cmp.l #fin_texte,a2
503     bne saute_init_texte
504     move.l #texte,offset_texte
505     saute_init_texte
506     rts
507    
508     vbl_on
509     move.w #$2700,sr
510     move.w #2,$454
511     move.b #199,$fffa21
512     move.l #hbl,$120
513     move.b #8,$fffa1b
514     move.l $4ce,sauve_4ce
515     move.l $4d2,sauve_4d2
516     move.l #vbl,$4ce
517     move.b #%00000001,$fffa07
518     move.b #%00000001,$fffa13
519     moveq.l #1,d0
520     jsr music
521     move.l #music+8,$4d2
522     move.w #$2300,sr
523     rts
524    
525     vbl_off
526     move.l sauve_4ce,$4ce
527     move.l sauve_4d2,$4d2
528     move.b #0,$ffa21
529     move.b #0,$fffa1b
530     move.l #$ff8800,a0
531     move.w #$0800,d0
532     movep.w d0,(a0)
533     move.w #$0900,d0
534     movep.w d0,(a0)
535     move.w #$0A00,d0
536     movep.w d0,(a0)
537     rts
538    
539     hbl
540     palette_2
541     move.b #1,$fffa21
542     bclr #0,$fffa0f
543     rte
544    
545     vbl
546     palette_1
547     move.l #hbl,$120
548     clr.b $fffa1b
549     move.b #150,$fffa21
550     move.b #8,$fffa1b
551     rts
552    
553     charge_graphiques
554     move.l #boule,a0
555     lea buf_x15_balle,a1
556     move.l #44-1,d0
557     recopie_boule
558     move.l (a0)+,(a1)+
559     dbra d0,recopie_boule
560     rts
561    
562     convert
563     lea buf_x15_balle,a0
564     move.l #conv_1,a2
565     move.l #3,d5
566     next_couleur
567     move.l #352-1,d7
568     r_aff
569     move.w #15,d6
570     next_bit
571     roxl.w 4(a0)
572     roxl.w d4
573     roxl.w 2(a0)
574     roxl.w d4
575     roxl.w (a0)
576     roxl.w d4
577     and.w #%00000111,d4
578     move.b 0(a2,d4),d4
579     roxr.w d4
580     roxl.w d0
581     roxr.w d4
582     roxl.w d1
583     roxr.w d4
584     roxl.w d2
585     roxr.w d4
586     roxl.w d3
587     dbra d6,next_bit
588     move.w d0,(a0)+
589     move.w d1,(a0)+
590     move.w d2,(a0)+
591     move.w d3,(a0)+
592     dbra d7,r_aff
593     add.l #6,a2
594     dbra d5,next_couleur
595     rts
596    
597     cls
598     move.l buf1,a0
599     move.l buf2,a1
600     move.l #31999,d0
601     cls_1
602     clr.b (a0)+
603     clr.b (a1)+
604     dbra d0,cls_1
605     rts
606    
607     init_buffers
608     lea buf_x15_balle,a1 ; recopie
609     lea 2816*1(a1),a2
610     lea 2816*2(a1),a3
611     lea 2816*3(a1),a4
612     moveq #15,d2
613     recopie_2
614     lea buf_x15_balle,a0
615     rept 44
616     move.l (a0),(a1)+
617     move.l (a0),(a2)+
618     move.l (a0),(a3)+
619     move.l (a0)+,(a4)+
620     endr
621     dbra d2,recopie_2
622    
623     lea fin_x15_balle,a0 ; predecalle
624     move.l #4-1,d6
625     buffer_suivant
626     move.l #15,d5
627     scroll
628     move.l d5,d3
629     move.l #16,d0
630     sub.l d3,d0
631     move.l #88-1,d1
632     s1_2
633     move.w (a0),d4
634     move.w -8(a0),d2
635     lsr.w d3,d4 ; decalle de D3 rotations
636     lsl.w d0,d2
637     add.w d2,d4
638     move.w d4,(a0)
639     subq.l #2,a0
640     dbra d1,s1_2
641     dbra d5,scroll
642     dbra d6,buffer_suivant
643    
644     lea buf_x15_balle,a0 ; calcul des masques
645     lea buf_masque,a1
646     move.l #352-1,d0
647     calcule_masque
648     move.w (a0)+,d0
649     or.w (a0)+,d0
650     or.w (a0)+,d0
651     or.w (a0)+,d0
652     not d0
653     move.w d0,(a1)+
654     move.w d0,(a1)+
655     dbra d0,calcule_masque
656     rts
657    
658     initialisations
659     move.l #table_balle,offset_balle
660     move.l #texte,offset_texte
661     move.l #pos_texte,offset_pos_texte
662     rts
663    
664     gemdos_init:
665     move.l a7,a5
666     move.l 4(a5),a5
667     move.l $c(a5),d0
668     add.l $14(a5),d0
669     add.l $1c(a5),d0
670     add.l #$500,d0
671     move.l d0,d1
672     add.l a5,d1
673     and.l #-2,d1
674     move.l d1,a7
675     move.l d0,-(sp)
676     move.l a5,-(sp)
677     clr.w -(sp)
678     move.w #$4a,-(sp)
679     trap #1
680     add.l #12,sp
681     jmp debut_programme
682    
683     efface_palette
684     move.l a0,-(sp)
685     move.l d0,-(sp)
686     lea $ff8240,a0
687     move.l #7,d0
688     eff
689     clr.l (a0)+
690     dbra d0,eff
691     move.l (sp)+,d0
692     move.l (sp)+,a0
693     rts
694    
695     affiche_presentation
696     palette_1
697    
698     lea page_de_fonds,a0
699     move.l #8000-1,d0
700     efface_page
701     move.l #0,(a0)+
702     dbra d0,efface_page
703    
704     move.l #gfx_next,a0
705     lea page_de_fonds,a1
706     add.l #40,a1
707     move.l #46,d0
708     aff_nxt
709     rept 80
710     move.b (a0)+,(a1)+
711     endr
712     add.l #80,a1
713     dbra d0,aff_nxt
714    
715     move.l #gfx_next_2,a0
716     lea page_de_fonds,a1
717     add.l #72+47*160,a1
718     move.l #8,d0
719     aff_nxt_2
720     rept 24
721     move.b (a0)+,(a1)+
722     endr
723     add.l #136,a1
724     dbra d0,aff_nxt_2
725    
726     move.l #gfx_the,a0
727     lea page_de_fonds,a1
728     add.l #8+73*160,a1
729     move.l #44,d0
730     aff_the
731     rept 56
732     move.b (a0)+,(a1)+
733     endr
734     add.l #104,a1
735     dbra d0,aff_the
736    
737     move.l #gfx_charts,a0
738     lea page_de_fonds,a1
739     add.l #64+56*160,a1
740     move.l #82,d0
741     aff_chrt
742     rept 88
743     move.b (a0)+,(a1)+
744     endr
745     add.l #72,a1
746     dbra d0,aff_chrt
747     rts
748    
749     section DATA
750    
751     boule incbin "balls.dat"
752     gfx_the incbin "The.gfx"
753     gfx_next incbin "NeXT.gfx"
754     gfx_next_2 incbin "NeXT_2.gfx"
755     gfx_charts incbin "Charts.gfx"
756     gfx_fonte incbin "Fonte.gfx"
757     points incbin "star_160.dat"
758     table_balle incbin "next_160.coo"
759     fin_table_balle
760     music incbin "atomic.mus"
761     even
762    
763     texte incbin "message.txt"
764     fin_texte
765     even
766    
767     pos_texte
768     dc.l 160*151,160*150,160*149,160*148,160*147,160*146,160*145
769     dc.l 160*144,160*143,160*142
770     rept 50
771     dc.l 160*141
772     endr
773     dc.l 160*142,160*143,160*144,160*145,160*146,160*147,160*148
774     dc.l 160*149,160*150,160*151
775     dc.l 0
776    
777     conv_1 dc.b 00,01,02,03,04,05
778     conv_2 dc.b 00,01,06,07,08,09
779     conv_3 dc.b 00,01,10,11,12,13
780     conv_4 dc.b 00,01,12,13,14,15
781    
782     reg dc.l r
783     r dc.l 0,1,2,3,4,5,6,7,0,1,2,3,4,5,6,7
784    
785     section BSS
786    
787     val ds.l 1
788     sauve_pile ds.l 1
789     sauve_4ce ds.l 1
790     sauve_4d2 ds.l 1
791     sauve_reg ds.l 16
792     sauve_70 ds.l 1
793    
794     offset_pos_texte ds.l 1
795     offset_texte ds.l 1
796     offset_balle ds.l 1
797     buf ds.l 1
798     buf1 ds.l 1
799     buf2 ds.l 1
800    
801     even
802    
803     buf_ecran ds.b 64256
804     page_de_fonds ds.b 32000+10000
805    
806     buf_fonte ds.b 1280
807     fin_fonte
808    
809     buf_x15_balle ds.b 2816*4
810     fin_x15_balle
811    
812     buf_masque ds.b 1408*4
813     fin_masque
814    
815     end

  ViewVC Help
Powered by ViewVC 1.1.26